home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / cvttobm.pro < prev    next >
Text File  |  1997-07-08  |  3KB  |  122 lines
  1. ; $Id: cvttobm.pro,v 1.5 1997/01/15 03:11:50 ali Exp $
  2. ;
  3. ; Copyright (c) 1996-1997, Research Systems, Inc.  All rights reserved.
  4. ;    Unauthorized reproduction prohibited.
  5. ;
  6. ;+
  7. ; NAME: Cvttobm
  8. ;
  9. ; PURPOSE:
  10. ;    Converts a byte array in which each byte represents one pixel
  11. ;       into a bitmap byte array in which each bit represents one
  12. ;       pixel. This is useful when creating bitmap labels for buttons
  13. ;       created with the WIDGET_BUTTON function.
  14. ;
  15. ;       Bitmap byte arrays are monochrome; by default, CVTTOBM converts
  16. ;       pixels that are darker than the median value to black and pixels
  17. ;       that are lighter than the median value to white. You can supply
  18. ;       a different threshold value via the THRESHOLD keyword.
  19. ;
  20. ;       Most of IDL's image file format reading functions (READ_BMP,
  21. ;       READ_PICT, etc.) return a byte array which must be converted
  22. ;       before use as a button label. Note that there is one exception
  23. ;       to this rule; the READ_X11_BITMAP routine returns a bitmap
  24. ;       byte array that needs no conversion before use.
  25. ;
  26. ; CATEGORY:
  27. ;
  28. ;       Widgets, button bitmaps
  29. ;
  30. ; CALLING SEQUENCE:
  31. ;
  32. ;    bitmap = Cvttobm(array [,THRESHOLD = Threshold])
  33. ; 
  34. ; INPUTS:
  35. ;    array - A 2-dimensional pixel array, one byte per pixel
  36. ;
  37. ;
  38. ; OPTIONAL INPUTS:
  39. ;       None
  40. ;
  41. ;
  42. ; KEYWORD PARAMETERS:
  43. ;
  44. ;    THRESHOLD - A byte value (or an integer value between 0 and 255)
  45. ;                   to be used as a threshold value when determining if
  46. ;                   a particular pixel is black or white. If not specified,
  47. ;                   the threshold is calculated to be the average of the
  48. ;                   input array.
  49. ;
  50. ; OUTPUTS:
  51. ;    bitmap - bitmap byte array, in which each bit represents one pixel
  52. ;
  53. ;
  54. ; OPTIONAL OUTPUTS:
  55. ;       None
  56. ;
  57. ;
  58. ; COMMON BLOCKS:
  59. ;       None
  60. ;
  61. ;
  62. ; SIDE EFFECTS:
  63. ;       None
  64. ;
  65. ;
  66. ; RESTRICTIONS:
  67. ;       None
  68. ;
  69. ;
  70. ; PROCEDURE:
  71. ; 1. Creates mask from input array, where values are 0/1 based on threshold.
  72. ; 2. Calculates the size of the output array.
  73. ; 3. Calculates the bitmap array from byte array based on mask.
  74. ;
  75. ; EXAMPLE:
  76. ;
  77. ; IDL> image=bytscl(dist(100))
  78. ; IDL> base=widget_base(/column)
  79. ; IDL> button=widget_button(base,value=Cvttobm(image))
  80. ; IDL> widget_control,base,/realize
  81. ;
  82. ;
  83. ; MODIFICATION HISTORY:
  84. ;       Created: Mark Rehder, 10/96
  85. ;       Modified: Lubos Pochman, 10/96
  86. ;-
  87.  
  88. function Cvttobm, array, THRESHOLD=threshold
  89.  
  90.     s = size(array)
  91.     if s[0] ne 2 then message, "Input array is not a 2D array!"
  92.     ;
  93.     ; Check the THRESHOLD keyword
  94.     ;
  95.     mask=bytscl(reverse(array,2))
  96.     if (N_ELEMENTS(THRESHOLD) eq 0) then threshold=total(mask)/n_elements(mask)
  97.     ;
  98.     ; Calculate mask based on threshold
  99.     ;
  100.     mask[where(mask lt threshold)]=0b
  101.     mask[where(mask ge threshold)]=1b
  102.     ;
  103.     ; Calculate the new size of the bitmap array
  104.     ;
  105.     s=size(mask) & cols=((s[1]-1)/8+1) & rows=s[2]
  106.     bmp=bytarr(cols,rows)
  107.     mult=[[1],[2],[4],[8],[16],[32],[64],[128]]
  108.     ;
  109.     ; Calculate the bitmap array from byte array based on mask
  110.     ;
  111.     vect=intarr(8)
  112.     for i=0,cols-1 do begin
  113.         for j=0,rows-1 do begin
  114.             temp=reform(mask[i*8:min([s[1]-1,i*8+7]),j])
  115.             vect[0:N_ELEMENTS(temp)-1]=temp
  116.             bmp[i,j]=byte(vect##mult)
  117.         endfor
  118.     endfor
  119.  
  120.     return,bmp
  121. end
  122.